home *** CD-ROM | disk | FTP | other *** search
/ LOGIC Apps / Logic-APPLE_II_APPS.iso / mac / LOGIC Apple II 5.25" Library - ProDOS / PRO050.dsk / BASIC.COPY.2.bas < prev    next >
BASIC Source File  |  2012-02-16  |  3KB  |  95 lines
  1. 10  REM  ***  BASIC.COPY.2  *** (ProDos Inside & Out p.77)
  2. 20  HOME 
  3. 25 A$ = " ": HTAB 9: VTAB 8: INVERSE 
  4. 30  FOR I = 1 TO 25: PRINT A$;: NEXT : PRINT 
  5. 35  FOR I = 1 TO 8: HTAB 9: PRINT A$;: HTAB 33: PRINT A$: NEXT 
  6. 40  HTAB 9: VTAB 16
  7. 45  FOR I = 1 TO 25: PRINT A$;: NEXT : PRINT : NORMAL 
  8. 50  HTAB 16: VTAB 10: PRINT "CheckWriter"
  9. 55  HTAB 20: VTAB 12: PRINT "by"
  10. 60  HTAB 14: VTAB 14: PRINT "Howard R. Cohen"
  11. 61  HTAB 24: VTAB 15: PRINT "(c) 1987"
  12. 65  GOSUB 1000
  13. 70 P1$ = PD$
  14. 110  REM  P1$= prefix of volume that files are to be copied FROM (MAY BE DEFINED IN CW)
  15. 120 P2$ = "/RAM/": REM  prefix of volume that files are to be copied TO
  16. 130 F$ = "ONGOING.DATA":T$ = "TXT": GOSUB 400: REM  names and types of files to copy
  17. 140 F$ = "MAIN.DATA":T$ = "TXT": GOSUB 400
  18. 150 F$ = "CAT.DATA":T$ = "TXT": GOSUB 400
  19. 160 F$ = "RECUR.TRANS":T$ = "TXT": GOSUB 400
  20. 170 F$ = "RECON.BAL.DATA":T$ = "TXT": GOSUB 400
  21. 180 F$ = "RT.CODE.DATA":T$ = "TXT": GOSUB 400
  22. 280  VTAB 22
  23. 290  VTAB 22: PRINT D$;"RUN /RAM/CW": REM  next program to run
  24. 300  END 
  25. 400 B = 0:A = 0:E = 0:L = 0: REM  Important--messing with this line can be fatal
  26. 405 X1 = 0:X2 = 0:CMD = 0
  27. 410  PRINT D$;"FRE"
  28. 420 A =  PEEK(109) + PEEK(110) *256
  29. 425 E =  PEEK(111) + PEEK(112) *256
  30. 430  ONERR  GOTO 500
  31. 440  PRINT D$;"CREATE";P2$;F$;",T";T$
  32. 450  PRINT D$;"BLOAD";P1$;F$;",T";T$;",A";A;",E";E -1;",B";B
  33. 455 CMD = 196: GOSUB 600:X1 =  PEEK(48825):X2 =  PEEK(48826)
  34. 460 L =  PEEK(48859) + PEEK(48860) *256
  35. 470  PRINT D$;"BSAVE";P2$;F$;",T";T$;",A";A;",L";L;",B";B
  36. 475 CMD = 195: POKE 48820,7: POKE 48825,X1: POKE 48826,X2: GOSUB 600
  37. 480  IF L = (E -A)  THEN B = B +L: GOTO 450
  38. 490  POKE 216,0: RETURN 
  39. 500  IF  PEEK(222) = 19  THEN  PRINT D$;"DELETE";P2$;F$: RESUME 
  40. 510  IF  PEEK(222) = 5  THEN  CALL  -3288: GOTO 490
  41. 512  IF  PEEK(222) = 6  THEN  CALL  -3288: GOTO 2000
  42. 514  IF  PEEK(222) = 8  THEN  CALL  -3288: GOTO 2000
  43. 520  PRINT "ERROR #"; PEEK(222);" IN LINE "; PEEK(218) + PEEK(219) *256
  44. 530  END 
  45. 580  GOTO 130
  46. 600  REM  *** MLI caller for use with BASIC.SYSTEM ***
  47. 610  POKE 48728,169: POKE 48729,CMD: POKE 48730,32
  48. 620  POKE 48731,112: POKE 48732,190: POKE 48733,176
  49. 630  POKE 48734,170: POKE 48735,96: CALL 48728: RETURN 
  50. 1000 D$ =  CHR$(4)
  51. 1005  VTAB 18
  52. 1010  PRINT D$;"OPEN /RAM/DATA.LOC"
  53. 1020  PRINT D$;"READ /RAM/DATA.LOC"
  54. 1030  INPUT PD$
  55. 1040  PRINT D$;"CLOSE /RAM/DATA.LOC"
  56. 1050  RETURN 
  57. 2000  REM  ONERR ROUTINE
  58. 2010  PRINT D$;"PR#3"
  59. 2020  HOME 
  60. 2025  HTAB 23: VTAB 5
  61. 2030  PRINT "YOUR PATHNAME IS AMOUNG THE MISSING"
  62. 2035  HTAB 1: VTAB 8
  63. 2040  INPUT "PLEASE ENTER THE PATHNAME OF YOUR DATA DISK /";X$
  64. 2050 PD$ = "/" +X$ +"/"
  65. 2055  HTAB 13: VTAB 12
  66. 2060  PRINT "DO YOU WANT TO <S>AVE THIS PATHNAME FOR PERMANENT USE?"
  67. 2070  HTAB 40: VTAB 14: GET X$
  68. 2080  IF X$ = "S"  OR X$ = "s"  THEN 2500
  69. 2090  GOTO 3000
  70. 2500  REM  SAVE PATH
  71. 2510  PRINT D$;"PREFIX";PP$
  72. 2520  PRINT D$;"OPEN DATA.LOC"
  73. 2530  PRINT D$;"WRITE DATA.LOC"
  74. 2540  PRINT PD$
  75. 2550  PRINT D$;"CLOSE DATA.LOC"
  76. 2560  PRINT D$;"PREFIX /RAM"
  77. 2570  PRINT D$;"OPEN DATA.LOC"
  78. 2580  PRINT D$;"WRITE DATA.LOC"
  79. 2590  PRINT PD$
  80. 2595  PRINT D$;"CLOSE DATA.LOC"
  81. 2700  HOME 
  82. 2710  HTAB 1: VTAB 18
  83. 2720  PRINT PD$;" HAS BEEN SAVED AS THE DATA LOCATION"
  84. 2730  HTAB 27: VTAB 21
  85. 2740  PRINT "PRESS <ANY KEY> TO CONTINUE"
  86. 2750  HTAB 40: VTAB 22
  87. 2760  GET X$
  88. 3000  HOME 
  89. 3005  HTAB 25: VTAB 12
  90. 3010  PRINT "LOADING CheckWriter DATA FROM"
  91. 3012 H = 40 - INT(.5 *( LEN(PD$)))
  92. 3014  HTAB H: VTAB 13
  93. 3016  PRINT PD$
  94. 3020  PRINT D$;"PREFIX /RAM"
  95. 3030  GOTO 70